Suche
  • Webdesign | SEO | Affiliate Marketing
  • s.reinsprecht@stebdesign.de | +49 (0) 7432 - 5040212
Suche Menü

Excel-Haushaltsbuch selbst erstellen

Excel-Haushaltsbuch-Vorlage selbst erstellen

Ein selbst erstelltes Excel-Haushaltsbuch ist einer der ersten Schritte auf dem Weg in die finanzielle Freiheit. Aber auch dann, wenn die persönlichen Ziele anders aussehen, ist die Erstellung einer solchen Vorlage Investition in die eigene Person. Nur wer weiß, was am Ende jeden Monats unterm Strich übrigbleibt, kann dieses Geld sinnvoll und bestenfalls nachhaltig anlegen.

Ich zeige dir hier in einer Anleitung Schritt für Schritt, wie du dir ein Excel-Haushaltsbuch selbst erstellen kannst.

Excel-Haushaltsbuch selbst erstellen – Warum eigentlich?

Im Netz gibt es genügend Excel-Haushaltsbuch-Vorlagen. Es wäre also ein Leichtes, einfach eine vorhandene herunterzuladen und mit eigenen Werten zu füllen. Jedoch sind diese nicht immer und für alle ohne Weiteres verwendbar. Außerdem sind viele der Tabellen einfach schlecht erstellt und wenig durchdacht. Müssen Änderungen bzgl. anderer Einnahme- oder Ausgabenarten gemacht werden, so muss oft erst einmal der Aufbau der Tabellen und Formeln nachvollzogen werden. Möchte man die Auswertung individualisieren, sei es tabellarisch oder eben grafisch in Form von Diagrammen, so muss man diese meist eh selbst erstellen. Meiner Meinung nach gibt es also viele Nachteile fertiger Haushaltsbuch-Vorlagen, die mich dazu veranlasst haben, eine eigene zu erstellen.

Welche Vorteile habe ich, wenn ich eine Excel-Haushaltsbuch-Vorlage selbst erstelle?

  • Intensive Auseinandersetzung mit den Einnahmen und Ausgaben:
    Bei der Erstellung eines Haushaltsbuchs muss man sich zwangsläufig mit den eigenen Finanzen auseinandersetzen. Und der erste Aha-Effekt kommt meist schon, wenn man sich mit der Kategorisierung der Ausgaben befasst. Für eine spätere Auswertung ist es wichtig, die Kosten sinnvoll zu bündeln. Nur so können mögliche Sparpotenziale ausfindig gemacht und genutzt werden. Wer genau weiß, was er oder sie einnimmt, kann nachhaltig mit seinen Finanzen wirtschaften und ein optimales Haushaltsbudget planen. Bleibt am Ende eines Monats ein positiver Saldo übrig (was immer das Ziel sein sollte), wird das Geld möglichst automatisiert gespart.
  • Individuelle Möglichkeiten zur Gestaltung und Auswertung:
    Eine eigene Excel-Haushaltbuch-Vorlage ist flexibel. Unnütze Dinge, wie sie oft in kostenlosen Downloads enthalten sind, können pauschal von Anfang an weggelassen werden. Man kann sich auf das Wesentliche und auf das individuell Relevante konzentrieren. Und das wichtigste, alle Tabellen lassen sich personalisieren (Tabelleninhalte + Design).
  • Excel-Kenntnisse auffrischen und vertiefen:
    Eine einfache Addition, Subtraktion oder ein Produkt bekommen die meisten hin. Die Ermittlung des Mittelwerts oder der Anzahl von Werten in einer Zeile oder Spalte ist auch noch geläufig. Aber dann hört es oft schon auf. Ein weiterer guter Grund, weshalb es Sinn macht, ein eigenes Haushaltsbuch zu programmieren. Wenn man mal etwas nicht weiß, wird die Suche einfach in die Suchmaschine eingegeben. Für fast jedes Problem gibt es im Netz eine Lösung. Und hat man dann die Excel-Vorlage erstellt und womöglich noch ein paar außergewöhnliche Formeln benutzt, kann man doppelt so stolz sein – man hat sich mit seinen Finanzen auseinandergesetzt und man hat noch ein paar Excel-Kenntnisse dazugelernt.

Schritt für Schritt zur eigenen Excel-Haushaltsbuch-Vorlage

Intelligente Tabellen nutzen

Bevor es ins Eingemachte geht, möchte ich noch auf ein sinnvolles Feature von Excel aufmerksam machen, welches noch viel zu selten wirklich genutzt wird: intelligente Tabellen.

Jede Tabelle, die ich erstelle, versehe ich sozusagen mit einer Intelligenz, auf die ich hier aber nicht weiter eingehen möchte. Nur so viel: es erleichtert geplante Auswertungen und macht aufwändigere Formeln übersichtlicher. Nutzen kann man die Funktionalität, wenn die jeweiligen Tabellen über die Menü-Schaltfläche Als Tabelle formatieren formatiert werden. Oder noch schneller, mit dem Shortcut Strg + T in Windows bzw. cmd + T in MacOS.

Wird nichts manipuliert, so benennt Excel die intelligenten Tabellen von Tabelle1 bis TabelleX. Um das Ganze noch ein wenig übersichtlicher zu halten, benenne ich die Tabellen in folgendem Schema:

  • Tabellen zur Auswertung und Erfassung der Daten
    • tab_Tabellenname
  • Hilfstabellen
    • hilfstab_Tabellenname

Der Menüpunkt Tabelle gibt die Möglichkeit, die einzelnen Tabellen mit unterschiedlichen Tabellenvorlagen zu formatieren. Dies nutze ich natürlich, so z.B. für die Ausgaben (orange), Einnahmen (grün) und den Sparplan (blau).

Excel-Haushaltsbuch selbst erstellen - Tabellen benennen und formatieren
Excel-Haushaltsbuch-Vorlage – Tabellen benennen und formatieren

Hilfstabellen

Meine Einnahmen, Ausgaben und Sparraten möchte ich in sinnvolle Kategorien verbuchen. Hierfür eignet sich besonders gut eine Auswahlliste. Um den Überblick zu behalten, erstelle ich also ein neues Tabellenblatt Hilfstabellen. Dort werden alle notwendigen Tabellen in Form intelligenter Tabellen angelegt:

  • Einnahmenart (hilfstab_Einnahmen)
  • Ausgabenart (hilfstab_Ausgaben_fix, hilfstab_Ausgaben_variabel)
  • Sparart (hilfstab_Sparen)
Excel-Haushaltsbuch - Hilfstabellen
Hilfstabellen für die Ausgaben-, Einnahmen- und Spararten

Falls notwendig, können diese dann ohne Weiteres bearbeitet und/ oder erweitert werden.

Ausgaben erfassen

Bei den meisten kostenlos angebotenen Excel-Haushaltsbüchern müssen die Ausgaben direkt in die Übersichtstabelle eingegeben werden. Natürlich in die jeweilige Ausgabenart bzw. -kategorie. Doch was ist, wenn es mal mehrere Kosten derselben Kategorie gibt? In dem Fall könnte man die einzelnen Posten (z.B. in Form von Kassenzetteln) sammeln und um Ende des Monats als Gesamtsumme eintragen. Oder man trägt in der betroffenen Zelle eine Summe aus den einzelnen Posten ein. Dann kann man letztendlich aber nicht mehr wirklich nachvollziehen, was die einzelnen Werte der Summe bedeuten. Ggf. wird sogar mal ein Wert vergessen.

Ich wollte eine bessere Lösung der Ausgabenerfassung. Deshalb erstelle ich ein separates Tabellenblatt Ausgaben. Hier trage ich dann alle Ausgaben ein, die chronologisch über das ganze Jahr verteilt anfallen. Dabei wird jede einzelne Ausgabe mit Datum, Ausgabenart und anfallende Kosten angegeben. Außerdem kann die Spalte Bemerkung genutzt werden, um Ausgaben rückwirkend besser nachvollziehen zu können.

Excel-Haushaltsbuch - Ausgaben erfassen
Tabelle tab_Ausgaben – Datum, fixe oder variable Ausgaben, Kosten, Bemerkung

Für die Spalte Ausgabenart (fix, variabel) nutze ich eine Auswahlliste. Diese kann im Menüpunkt Daten Datenüberprüfung programmiert werden. Als Gültigkeitskriterium wähle ich die Liste und unter Quelle wird die erstellte Hilfstabelle für die Ausgabenarten angegeben. Hier unterscheide ich auch direkt zwischen fixen und variablen Ausgaben:

=INDIREKT("Hilfstabellen!hilfstab_Ausgaben_fix[Ausgabenart fix]")
=INDIREKT("Hilfstabellen!hilfstab_Ausgaben_variabel[Ausgabenart variabel]")
Excel Auswahlliste festlegen (fixe Ausgaben)
Auswahlliste festlegen (fixe Ausgaben)

Einnahmen erfassen

Mit den Einnahmen handhabe ich es ähnlich wie mit den Ausgaben. Auch diese werden in einem separaten Tabellenblatt Einnahmen chronologisch aufgelistet. So kann ich einerseits nachvollziehen, wann wie viel Geld eingegangen ist und andererseits automatisch (per Formel) mehrere derselben Einnahmenart in der Auswertung zusammenrechnen.

Excel-Haushaltsbuch - Einnahmen erfassen
Tabelle tab_Einnahmen – Datum, Einnahmenart, Wert, Bemerkung

Auch hier nutze ich die Auswahlliste wie ich bei den Ausgaben schon beschrieben habe. Die Formel für die Quelle:

=INDIREKT("Hilfstabellen!hilfstab_Einnahmen[Einnahmenart]")

Zusatz – Sparplan erfassen

Bei den Sparraten gibt es unterschiedliche Meinungen, wenn es um die Erfassung im Haushaltsbuch geht. Ich habe mir lange Gedanken gemacht und bin letztendlich zu der Lösung gekommen, die Sparraten ebenfalls in einem separaten Tabellenblatt Sparen aufzulisten.

Genaugenommen sind die Raten, mit denen z.B. ein Tagesgeldkonto gefüllt oder einen ETF-Sparplan bedient wird, ja keine Ausgaben. Jedoch werden sie in Form einer Ausgabe monatlich vom Girokonto abgebucht. Also doch eine Ausgabe? Jein…, jedenfalls nicht in meiner Excel-Haushaltsplan-Vorlage. Hier kann und sollte aber jede(r) selbst entscheiden, wie er oder sie dies sehen möchte.

Für die Aufteilung der Sparraten achte ich auf die monatlichen Saldi. Die Raten sollten insgesamt nicht höher, aber auch nicht wesentlich geringer als das jeweils verfügbare Saldo liegen.

Excel-Haushaltsbuch - Sparraten erfassen
Tabelle tab_Sparen – Datum, Geldanlage, Rate, Bemerkung

Die Auswahl der Sparart erreiche ich auch hier wieder per Auswahlliste. Die Formel für die Quelle ändert sich dann entsprechend zu:

=INDIREKT("Hilfstabellen!hilfstab_Sparen[Sparart]")

Die Auswertung des Haushaltsbuchs

Bei der Auswertung des Haushaltsbuchs stelle ich mir zuerst die Fragen, was ich überhaupt messen will und wie ich diese Ergebnisse inhaltlich und optisch gestalten möchte. So komme ich auf folgende Anforderung für das Tabellenblatt Übersicht – Zahlen:

  • Monatliche kumulierte Auflistung und Auswertung der Eingaben
  • Übersichtliche und visuell unterscheidbare Tabellen
    • Schnellübersicht – Gesamteinnahmen, Gesamtausgaben und Saldo
    • Einnahmen
    • Ausgaben (fix)
    • Ausgaben (variabel)
    • Sparplan

Außerdem erstelle ich noch ein weiteres Tabellenblatt Überblick – Diagramme:

  • Grafische Auswertung in Form von Diagrammen
    • Schnellübersicht
    • Sparplan mit kumulierten Werten

Schnellübersicht – Gesamteinnahmen, Gesamtausgaben, Saldo

Die Tabelle mit der Schnellübersicht wird als erstes gelistet. Denn sie zeigt mir direkt, wie viel ich im jeweiligen Monat insgesamt eingenommen und ausgegeben habe. Außerdem sehe ich mit dem Saldo, also die Gesamteinnahmen minus die Gesamtausgaben, direkt, wie viel ich spare oder gar, ob ich über meine Verhältnisse lebe.

Gesamteinnahmen: alle aufsummierten Einnahmen eines Monats

=tab_Einnahmen_ges[[#Ergebnisse];[Januar]]

Gesamtausgaben: alle aufsummierten fixe und variable Ausgaben eines Monats

=tab_Ausgaben_fix[[#Ergebnisse];[Januar]]+tab_Ausgaben_variabel[[#Ergebnisse];[Januar]]
Excel-Haushaltsbuch - Schnellübersicht (Gesamtausgaben, Gesamteinnahmen, Saldo)
Tabelle Schnellübersicht – Gesamtausgaben, Gesamteinnahmen und Saldo

Per bedingter Formatierung erstelle ich eine Regel, die das Saldo entsprechend automatisch formatieren soll. Werte > 0 sollen grün und Werte < 0 sollen rot markiert werden. Das persönliche Ziel sollte dann natürlich immer ein unterm Strich positiver, also ein grün formatierter Saldo sein.

Excel bedingte Formatierung (Regeln)
Bedingte Formatierung – Saldo wird entsprechend per Regel formatiert

Damit die Tabelle Schnellübersicht beim Scrollen immer sichtbar bleibt, fixiere ich sie – Ansicht Fenster fixieren.

Auswertung – Einnahmen, Ausgaben und Sparplan

Die Tabellen zur Auswertung der Einnahmen (tab_Einnahmen_ges), Ausgaben (tab_Ausgaben_fix, tab_Ausgaben_variabel) und Sparraten (tab_Sparen_ges) sind im Prinzip immer gleich aufgebaut:

  • Tabellenspalten: monatliche Auflistung der kompletten Einnahmen, Ausgaben und Sparraten
  • Erste Spalte: automatisierte Auflistung der Kategorien der einzelnen Hilfstabellen (Einnahmenarten, Ausgabenarten – aufgeteilt in fixe und variable Ausgaben, Spararten)
  • Tabellenzeilen: einzelne kumulierte Werte der jeweiligen Kategorien
  • Ergebniszeile: die Summen der jeweiligen Monate – dies ist eine praktische Funktion der intelligenten Tabelle
  • Ergebnisspalte: die Jahressummen, also die Summen der einzelnen Monate

Wie so oft führen bekanntlich viele Wege nach Rom. Die folgenden Formeln müssen nicht zwangsläufig die effizienteste Art sein, aber sie sind effektiv und führen zum gewünschten Ziel. Bei deren Erstellung habe ich versucht, möglichst viel zu automatisieren. Außerdem habe ich überlegt, wo beim Führen des Haushaltsbuchs theoretisch Fehler gemacht und wie diese vermieden werden können.

Im Folgenden beziehe ich mich auf die Formeln für die Auswertungstabelle der Einnahmen. Die Formeln für die Ausgaben (fix und variabel) sowie für den Sparplan füge ich jeweils unten als Ergänzung an. Sie funktionieren auf dieselbe Art.

INDEX-Formel für die Auflistung der einzelnen Kategorien

Eine mögliche Fehlerquelle könnte z.B. sein, dass in der Auswertungstabellen einzelne Kategorien vergessen werden. Beispielsweise dann, wenn Kategorien in den Hilfstabellen geändert oder weitere hinzugefügt werden. Die entsprechende Tabelle für die Auflistung der Kategorien ist deshalb direkt mit den Hilfstabellen verknüpft.

Kategorien per INDEX-Formel auflisten
Per INDEX-Formal alle Kategorien auflisten
=@INDEX(INDIREKT("hilfstab_Einnahmen[Einnahmenart]");AGGREGAT(15;6;ZEILE(INDIREKT("hilfstab_Einnahmen[Einnahmenart]"))/(INDIREKT("hilfstab_Einnahmen[Einnahmenart]")<>"");ZEILE()-ZEILE(tab_Einnahmen_ges[[#Kopfzeilen];[Einnahmen]]))-1;1)

Diese etwas komplexere Index-Formel geht im Prinzip Zeile für Zeile der Hilfstabelle hilfstab_Einnahmen durch und gibt bis zum letzten Eintrag alle Zellwerte aus, die nicht leer sind. Es werden also alle Kategorien nacheinander aufgelistet.

Nun muss ich nur noch darauf achten, dass die Auswertungstabelle mit ausreichend vielen Zeilen versehen ist. So viele, dass bis zur letzten Kategorie alle aufgelistet werden können. Füge ich also in der Hilfstabelle eine hinzu, so muss ich parallel auch eine weitere Zeile in der Auswertungstabelle hinzufügen. Dies birgt natürlich noch ein gewisses Fehlerpotential.

Ggf. gibt es hier also noch eine bessere Lösung. Um aber dennoch in der Auswertung garantiert keine Kategorie zu vergessen, hilft folgende Vorgehensweise:

  • Eine Zeile mehr hinzufügen: Wird die Auswertungstabelle mit so vielen Zeilen aufgefüllt, bis die letzte leer bleibt, sind definitiv alle Kategorien aufgelistet worden.
  • ANZAHL2 als Kontrollfunktion: Es gäbe die Möglichkeit, die Kategorien in der Hilfstabelle und gelisteten in der Auswertungstabelle per ANZAHL2 zu zählen. Per bedingter Formatierung könnte man dann beide Ergebnisse so formatieren, dass sie Rot angezeigt werden, wenn beide unterschiedlich sind und grün, wenn sie gleich sind.
Ergänzende INDEX-Formeln:

Ausgaben (fix)

=@INDEX(INDIREKT("hilfstab_Ausgaben_fix[Ausgabenart fix]");AGGREGAT(15;6;ZEILE(INDIREKT("hilfstab_Ausgaben_fix[Ausgabenart fix]"))/(INDIREKT("hilfstab_Ausgaben_fix[Ausgabenart fix]")<>"");ZEILE()-ZEILE(tab_Ausgaben_fix[[#Kopfzeilen];[Ausgaben (fix)]]))-1;1)

Ausgaben (variabel)

=@INDEX(INDIREKT("hilfstab_Ausgaben_variabel[Ausgabenart variabel]");AGGREGAT(15;6;ZEILE(INDIREKT("hilfstab_Ausgaben_variabel[Ausgabenart variabel]"))/(INDIREKT("hilfstab_Ausgaben_variabel[Ausgabenart variabel]")<>"");ZEILE()-ZEILE(tab_Ausgaben_variabel[[#Kopfzeilen];[Ausgaben (variabel)]]))-1;1)

Sparen

=@INDEX(INDIREKT("hilfstab_Sparen[Sparart]");AGGREGAT(15;6;ZEILE(INDIREKT("hilfstab_Sparen[Sparart]"))/(INDIREKT("hilfstab_Sparen[Sparart]")<>"");ZEILE()-ZEILE(tab_Sparen_ges[[#Kopfzeilen];[Sparen]]))-1;1)

SUMMENPRODUKT-Formel für das Aufsummieren der monatlichen Werte:

Um mehrere Werte derselben Kategorie im jeweiligen Monat zu addieren, habe ich mich für das SUMMENPRODUKT entschieden. Genauso wäre aber auch eine Formel mit SUMMEWENNS möglich.

SUMMENPRODUKT-Formel für die Kumulierung gleicher Kategorien desselben Monats
Per SUMMENPRODUKT-Formal dieselben Kategorien im jeweiligen Monat aufsummieren
=SUMMENPRODUKT((INDIREKT("tab_Einnahmen[Art]")=$A8)*(MONAT(INDIREKT("tab_Einnahmen[Datum]"))=MONAT("1."&tab_Einnahmen_ges[[#Kopfzeilen];[Januar]]))*INDIREKT("tab_Einnahmen[Wert]"))

Die ersten beiden Argumente prüfen eine Bedingung und das letzte Argument gibt an, welcher Wert bzw. welche Werte einer bestimmten Spalte zur Summenbildung verwendet werden soll.

  • Argument 1: (INDIREKT(„tab_Einnahmen[Art]“)=$A8)
    Hier wird die Spalte Art der Tabelle tab_Einnahmen Zeile für Zeile durchsucht und mit der Kategorie verglichen, die links in der ersten Spalte steht. Die absolute Spalten- und relative Zeilenangabe $A8 muss natürlich entsprechend der tatsächlichen Position der Tabelle angepasst werden.
  • Argument 2: (MONAT(INDIREKT(„tab_Einnahmen[Datum]“))=MONAT(„1.“&tab_Einnahmen_ges[[#Kopfzeilen];[Januar]]))
    Hier wird die die Spalte Datum der Tabelle tab_Einnahmen Zeile für Zeile durchsucht und mit dem entsprechenden Monat in der Kopfzeile derselben Spalte verglichen – also mit Januar.
  • Argument 3: INDIREKT(„tab_Einnahmen[Wert]“)
    Immer dann, wenn die ersten beiden Argumente übereinstimmen, wird der Wert zu einer Gesamtsumme addiert.

Treten also mehrere Einnahmen derselben Kategorie im selben Monat auf, werden sie insgesamt zu einer Gesamteinnahme aufsummiert.

Ergänzende SUMMENPRODUKT-Formeln:

Ausgaben (fix)

=SUMMENPRODUKT((INDIREKT("tab_Ausgaben[fix]")=$A46)*(MONAT(INDIREKT("tab_Ausgaben[Datum]"))=MONAT("1."&tab_Ausgaben_fix[[#Kopfzeilen];[Januar]]))*INDIREKT("tab_Ausgaben[Kosten]"))

Ausgaben (variabel)

=SUMMENPRODUKT((INDIREKT("tab_Ausgaben[variabel]")=$A77)*(MONAT(INDIREKT("tab_Ausgaben[Datum]"))=MONAT("1."&tab_Ausgaben_variabel[[#Kopfzeilen];[Januar]]))*INDIREKT("tab_Ausgaben[Kosten]"))

Sparen

=SUMMENPRODUKT((INDIREKT("tab_Sparen[Geldanlage]")=$A108)*(MONAT(INDIREKT("tab_Sparen[Datum]"))=MONAT("1."&tab_Ausgaben_variabel[[#Kopfzeilen];[Januar]]))*INDIREKT("tab_Sparen[Rate]")) 

Visualisierung – Diagramme

Zur besseren Veranschaulichung der Daten der Schnellübersicht eignet sich ein einfaches Säulendiagramm (gestapelte Säulen).

Excel-Haushaltsbuch - Diagramm Jahresübersicht (gestapelte Säulen)
Diagramm Jahresübersicht (gestapelte Säulen)

Das Diagramm zeigt von Januar bis Dezember jeweils drei Säulen an – die Gesamteinnahmen, Gesamtausgaben und den Saldo des Monats. Der optische Geschmack ist natürlich unterschiedlich. Ich für mich habe entschieden, die Einnahmen entsprechend grün und die Ausgaben orange mit Musterfüllung zu formatieren. Der Saldo wird hingegen in einer einfarbigen Füllung angezeigt und invertiert, wenn er negativ wird. Im positiven Bereich ist er also wie die Einnahmen grün und im negativen Bereich ist er orange.

Datenquelle auswählen für Diagramm Jahresübersicht
Datenquelle auswählen für das Diagramm der Jahresübersicht

Ein weiteres interessantes Diagramm ist die Darstellung der aufsummierten Raten des Sparplans. Dieses setze ich ebenfalls als gestapelte Säulen um. Wirtschafte ich nachhaltig mit meinem Haushalsbudget und investiere den Überschuss in sinnvolle Geldanlagen, kann ich anhand der Balken sehen, wie meine Sparsumme Monat für Monat anwächst. Dies sollte ein visueller Ansporn zum Sparen sein.

Excel-Haushaltsbuch - Diagramm Sparplan mit kumulierten Werten (gestapelte Säulen)
Diagramm Sparplan mit kumulierten Werten (gestapelte Säulen)

Um die Sparsummen in kumulierter Form im Diagramm wiedergeben zu können, benötige ich noch eine Hilfstabelle (hilfstab_Sparen_kumuliert). Im Aussehen ist sie ein Abbild der Tabelle Sparen (tab_Sparen_ges). Eigentlich gehört sie in das Tabellenblatt Hilfstabellen, ich positioniere sie aber hier direkt daneben. Um die Kategorien automatisch in die erste Spalte einzufügen, kann ich dieselbe INDEX-Formel verwenden, wie oben schon beschrieben. Die Zelleninhalte benötigen aber eine Formel, die die Gesamtsparsummen der Monate aufsummiert. Diese sieht folgendermaßen aus:

=WENN(tab_Sparen_ges[@Januar]>0;SUMME($B108:tab_Sparen_ges[@Januar]);"")

Es wird also nur aufsummiert, wenn schon ein Wert im jeweiligen Monat erfasst wurde. Ansonsten bleibt die Zelle leer.

Datenquelle auswählen für Diagramm Sparplan
Datenquelle für das Diagramm Sparplan aus der Hilfstabelle auswählen

Schreibe einen Kommentar

Pflichtfelder sind mit * markiert.